2-2

up=(({{1}, {0}}));
dn=(({{0}, {1}}));
a_⊗b_:=KroneckerProduct[a,b]
CompConj[A_] := A /.Complex[0,n_]->-Complex[0,n]
Adj[x_]:=CompConj[Transpose[x]]
Comm[x_,y_]:=x.y-y.x
𝕀=(({{1, 0}, {0, 1}}));
(Subscript[𝕆, 8])=(({{0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}}));

Introduction to teleportation

Nicholas Wheeler
Reed College Physics Department
30 March 2010

Introduction

This sexy instance of "applied entanglement" was devised by Charles Bennet

Hyperlink["Charles Bennet","http://www.research.ibm.com/people/b/bennetc/"]

and colleagues (who included William Wootters and Asher Peres)

Hyperlink["Teleportation Discovery Team","http://www.research.ibm.com/quantuminfo/teleportation/"]

who published "Teleporting an unknown quantum state via dual classical and EPR channels," Phys. Rev. Letters 70, 1895-1899 in 1993.

Here—following the pattern of the discussion on pages 94-99 in Chapter 1 of Quantum II Notes (2009)—I first sketch the basic strategy, pulling matrices out of the hat, as needed, then back up to indicate how those matrices acquired their magical properties.

The initial set-up

Alice has two qubits, Bob has one. One of Alice's qubits is in the unknown state

The other is entangled with Bob's, the entangled pair being in (let us say) the Bell state

Bell=((up⊗up+dn⊗dn)/(Sqrt[2]));

So the initial state of the 3-qubit system is

(Subscript[Ψ, 0])=(({{(Subscript[ψ, 1])}, {(Subscript[ψ, 2])}}))⊗Bell;

(Subscript[Ψ, 0])//MatrixForm

Step one

Alice executes a dynamical unitary transformation (not a measurement) that serves to entangle her qubits. Specifically, she uses

𝕌=(1/(Sqrt[2]))(({{1, 0, 0, 1}, {0, 1, 1, 0}, {1, 0, 0, -1}, {0, 1, -1, 0}}));

to construct

(Subscript[Ψ, 1])=(𝕌⊗𝕀).(Subscript[Ψ, 0]);
(Subscript[Ψ, 1])//MatrixForm

Step two

Alice uses

𝔸=(({{1, 0}, {0, -1}}));

to construct meters  𝔸⊗𝕀 and 𝕀⊗𝔸, which in the composite theory become

(Subscript[𝔸, 1])=(𝕀⊗𝔸)⊗𝕀;
(Subscript[𝔸, 2])=(𝔸⊗𝕀)⊗𝕀;

(Subscript[𝔸, 1])//MatrixForm
(Subscript[𝔸, 2])//MatrixForm

The spectra of these matrices are obvious even without calculation

Eigenvalues[(Subscript[𝔸, 1])]
Eigenvalues[(Subscript[𝔸, 2])]

and so are their spectral resolutions (which we will need to obtain the results of 𝔸-measurements): defining

(Subscript[𝔸, 1up])=(({{1, 0, 0, 0, 0, 0, 0, 0}, {0, 1, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 1, 0, 0, 0}, {0, 0, 0, 0, 0, 1, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}}));
(Subscript[𝔸, 1dn])=(({{0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 1, 0, 0, 0, 0, 0}, {0, 0, 0, 1, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 1, 0}, {0, 0, 0, 0, 0, 0, 0, 1}}));
(Subscript[𝔸, 2up])=(({{1, 0, 0, 0, 0, 0, 0, 0}, {0, 1, 0, 0, 0, 0, 0, 0}, {0, 0, 1, 0, 0, 0, 0, 0}, {0, 0, 0, 1, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}}));
(Subscript[𝔸, 2dn])=(({{0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 0, 0, 0, 0}, {0, 0, 0, 0, 1, 0, 0, 0}, {0, 0, 0, 0, 0, 1, 0, 0}, {0, 0, 0, 0, 0, 0, 1, 0}, {0, 0, 0, 0, 0, 0, 0, 1}}));

we have

(Subscript[𝔸, 1])==(Subscript[𝔸, 1up])-(Subscript[𝔸, 1dn])
(Subscript[𝔸, 2])==(Subscript[𝔸, 2up])-(Subscript[𝔸, 2dn])

It is obvious also that the 𝔸-matrices commute

Comm[(Subscript[𝔸, 1]),(Subscript[𝔸, 2])]==(Subscript[𝕆, 8])

so the associated meters are compatible, can be used in either order. And each, when used, announces ±1.

Alice makes a pair of measurements

One or another of these four things happen:

1. Meters announce {+, +} and prepare the state given by

(Subscript[Ψ, upup])=2(Subscript[𝔸, 2up]).(Subscript[𝔸, 1up]).(Subscript[Ψ, 1])

where the 2 is a normalization factor.

2. Meters announce {+, -} and prepare the state given…by

(Subscript[Ψ, updn])=2(Subscript[𝔸, 2up]).(Subscript[𝔸, 1dn]).(Subscript[Ψ, 1])

3. Meters announce {-, +} and prepare the state given…by

(Subscript[Ψ, dnup])=2(Subscript[𝔸, 2dn]).(Subscript[𝔸, 1up]).(Subscript[Ψ, 1])

4. Meters announce {-, -} and prepare the state given…by

(Subscript[Ψ, dndn])=2(Subscript[𝔸, 2dn]).(Subscript[𝔸, 1dn]).(Subscript[Ψ, 1])

Alice reports her results by carrier pigeon to Bob

Bob reacts to the news

Bob is equipped with meters

𝕏=(𝕀⊗𝕀)⊗(({{0, 1}, {1, 0}}));
ℤ=(𝕀⊗𝕀)⊗(({{1, 0}, {0, -1}}));

1. If Alice reports {+,+} Bob does nothing, because he knows his qubit is now in the state (({{(Subscript[ψ, 1])}, {(Subscript[ψ, 2])}})):

(Subscript[Ψ, upup])==(up⊗up)⊗(({{(Subscript[ψ, 1])}, {(Subscript[ψ, 2])}}))

2. If Alice reports {+, -} Bob does an 𝕏-measurement, thus placing his qubit in the state (({{(Subscript[ψ, 1])}, {(Subscript[ψ, 2])}})):

𝕏.(Subscript[Ψ, updn])==(up⊗dn)⊗(({{(Subscript[ψ, 1])}, {(Subscript[ψ, 2])}}))

3. If Alice reports {-, +} Bob does an ℤ-measurement, thus placing his qubit in the state (({{(Subscript[ψ, 1])}, {(Subscript[ψ, 2])}})):

ℤ.(Subscript[Ψ, dnup])==(dn⊗up)⊗(({{(Subscript[ψ, 1])}, {(Subscript[ψ, 2])}}))

4. If Alice reports {-, -} Bob does first an 𝕏-measurement, then a ℤ-measurement, thus placing his qubit in the state (({{(Subscript[ψ, 1])}, {(Subscript[ψ, 2])}})):

ℤ.𝕏.(Subscript[Ψ, dndn])==(dn⊗dn)⊗(({{(Subscript[ψ, 1])}, {(Subscript[ψ, 2])}}))

In all cases, Bob's qubit has ended up in what had been the (then and still) unknown state of one of Alice's qubits. Violation of the no-clone theorem has been avoided because the state of Alice's qubit has been altered (is now known to be either up or dn).

Properties of some matrices of special quantum mechanical importance

I look now to the distinguishing features of some of the matrices that Bennet et al were content to pluck from their hats.

NOT

The matrix

ℕ=(({{0, 1}, {1, 0}}));

acts on 2-vectors by "flipping" their elements:

ℕ.(({{a}, {b}}))//MatrixForm

In particular, it sends (({{1}, {0}}))⟶(({{0}, {1}})) and (({{0}, {1}}))⟶(({{1}, {0}})), so describes the action of what quantum computation people call a "not" gate.

ℕ is hermitian, so might refer to a meter, with read-out indicated by

Eigenvalues[ℕ]

But more importantly, ℕ is unitary, so refers to an action that might be executed in finite time as a quantum dynamical process, generated by a Hamiltonian. Working backwards from the spectral representation of ℕ

ℕ==(+1)(({{(1/2), (1/2)}, {(1/2), (1/2)}}))+(-1)(({{(1/2), -(1/2)}, {-(1/2), (1/2)}}))

one is led to the hermitian matrix

𝕟=(({{-(π/2), (π/2)}, {(π/2), -(π/2)}}));

which generates a t-dependent matrix

MatrixExp[-I 𝕟 t]//MatrixForm

that is unitary

Assuming[t∈Reals, MatrixForm[Simplify[ComplexExpand[Adj[%].%]]]]

(Adj[%].%)//MatrixForm

and at time t = 1 gives back ℕ:

ℕ==(({{(1/2) (1+Cos[π t]+I Sin[π t]), (1/2) (1-Cos[π t]-I Sin[π t])}, {(1/2) (1-Cos[π t]-I Sin[π t]), (1/2) (1+Cos[π t]+I Sin[π t])}}))/.t->1

CONTROLLED-NOT

The distinctive action of the matrix

ℂℕ=(({{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 0, 1}, {0, 0, 1, 0}}));

is illustrated by the equations

ℂℕ.(up⊗(({{a}, {b}})))==up⊗(({{a}, {b}}))
ℂℕ.(dn⊗(({{a}, {b}})))==dn⊗(({{b}, {a}}))

Whether or not the second element flips has been placed under the control of the first element.

Hyperlink["Controlled NOT Gate","http://en.wikipedia.org/wiki/Controlled_NOT_gate"]

Again, we have in hand a matrix that is simultaneously hermitian and unitary:

Adj[ℂℕ]==ℂℕ
Adj[ℂℕ].ℂℕ//MatrixForm

And that—because unitary—describes a state-transformation that might be executed (not by projective measurement but) in finite time as a quantum dynamical process, generated by a Hamiltonian. Arguing as before from the spectral representation of ℂℕ

ℂℕ==(+1)(({{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, (1/2), (1/2)}, {0, 0, (1/2), (1/2)}}))+(-1)(({{0, 0, 0, 0}, {0, 0, 0, 0}, {0, 0, (1/2), -(1/2)}, {0, 0, -(1/2), (1/2)}}))

we are led to construct the t-dependent unitary matrix

MatrixExp[-I (({{0, 0, 0, 0}, {0, 0, 0, 0}, {0, 0, -(π/2), (π/2)}, {0, 0, (π/2), -(π/2)}}))t]

which gives back ℂℕ at t = 1:

ℂℕ==%/.t->1

HADAMARD MATRIX

The matrix

ℍ=(1/(Sqrt[2]))(({{1, 1}, {1, -1}}));

—which is again both hermitian and unitary

Adj[ℍ]==ℍ
Adj[ℍ].ℍ//MatrixForm

—constitutes (except for the prefactor (2^(-1/2))) the simplest instance of a "Hadamard matrix." Such matrices are of fundamental importance in a great variety of pure and applied applications. They underlie the theory of "Hadamard masks" that are used to make most efficient use of weak signals in spectroscopy, and have become central to the language of quantum computation.

Hyperlink["Hadamard Matrices","http://en.wikipedia.org/wiki/Hadamard_matrix"]
Hyperlink["Hadamard Matrices & Applications","http://press.princeton.edu/titles/8342.html"]
Hyperlink["Wolfram re Hadamard","http://mathworld.wolfram.com/HadamardMatrix.html"]

Two Hadamard applications

The simple Hadamard matrix ℍ acquires interest for us because (1) the "Bell matrix"

𝔹=ℂℕ.(ℍ⊗𝕀);

𝔹//MatrixForm

—which is unitary but not hermitian

Adj[𝔹].𝔹//MatrixForm
Adj[𝔹]==𝔹

—acts on the basic unentangled states to produce maximally entangled Bell states:

𝔹.(up⊗dn)
𝔹.(dn⊗dn)
𝔹.(up⊗up)
𝔹.(dn⊗up)

We have here demonstrated an important fact: entanglement can be achieved by dynamical quantum motion (i.e., by unitary transformation), and so also therefore (at least in some cases) can disentanglement.

ℍ is of interest to us also because (2) it places us in position to construct

(ℍ⊗𝕀).ℂℕ//MatrixForm

which is precisely the (manifestly non-hermitian) unitary matrix

𝕌//MatrixForm

used by Alice at STEP ONE of the teleportation procedure. The spectrum of 𝕌 is relatively complicated

Eigenvalues[𝕌]

and so also—not surprisingly—are the eigenvectors, the projectors onto those eigenrays, the spectral resolution of 𝕌, and its hermitian generator. Calculation (along the now familiar lines) leads to

ℍ=(({{(((3-2 (Sqrt[2])) π)/(4 (-2+(Sqrt[2])))), (((3-2 (Sqrt[2])) π)/(4 (-2+(Sqrt[2])))), ((((2+2 I)-(2+I) (Sqrt[2])) π)/(8 (-2+(Sqrt[2])))), ((((2-2 I)-(2-I) (Sqrt[2])) π)/(8 (-2+(Sqrt[2]))))}, {(((3-2 (Sqrt[2])) π)/(4 (-2+(Sqrt[2])))), (((3-2 (Sqrt[2])) π)/(4 (-2+(Sqrt[2])))), ((((2-2 I)-(2-I) (Sqrt[2])) π)/(8 (-2+(Sqrt[2])))), ((((2+2 I)-(2+I) (Sqrt[2])) π)/(8 (-2+(Sqrt[2]))))}, {((((2-2 I)-(2-I) (Sqrt[2])) π)/(8 (-2+(Sqrt[2])))), ((((2+2 I)-(2+I) (Sqrt[2])) π)/(8 (-2+(Sqrt[2])))), (π/(4 (-2+(Sqrt[2])))), (π/(4 (-2+(Sqrt[2]))))}, {((((2+2 I)-(2+I) (Sqrt[2])) π)/(8 (-2+(Sqrt[2])))), ((((2-2 I)-(2-I) (Sqrt[2])) π)/(8 (-2+(Sqrt[2])))), (π/(4 (-2+(Sqrt[2])))), (π/(4 (-2+(Sqrt[2]))))}}));

I will not write out the matrix

but demonstrate that at  t = 1  we do have

𝕌==Simplify[MatrixExp[-I ℍ]]

The "Hamiltonian" ℍ can be written more simply

FullSimplify[ℍ]//MatrixForm

but (because of the buried i-factors?) Mathematica gets nowhere when it tries to work with that description of ℍ. The important point here is conceptual: the transformation

(Subscript[Ψ, 0]) ⟶ (Subscript[Ψ, 1])=(𝕌⊗𝕀).(Subscript[Ψ, 0])

undertaken by Alice at STEP ONE was a dynamical transformation.

Experimental teleportation

For an authoritative semi-popular account—by Zeilinger and his group—of photonic teleportation, see

Hyperlink["Photonic Teleportation","http://www.imit.kth.se/QEO/qucomm/DelD19QuComm.pdf"]

The first report of photon-mediated teleportation between distant atoms can be found at

Hyperlink["Material Teleportation","http://www.scienceonline.org/cgi/content/short/323/5913/486"]

Click on "Read the full text." Look also at the article by Kim & Cho cited under PERSPECTIVES at the bottom of the page.

In class I mentioned an old Mathematica resource that had been prepared by Charles Bennet, called QDensity, that provided palettes for simulating teleportation set-ups of several types, plus a lot of other material relating to the simulation of quantum computation. Seems to have been pulled from the web, but lots of other sites no make reference to (some more recent reincarnation?) of QDensity. One that looks promising is

Hyperlink["QDensity","http://www.sciencedirect.com/science?_ob=ArticleURL&_udi=B6TJ5-4JBGJ8J-1&_user=1510667&_coverDate=06%2F01%2F2006&_rdoc=1&_fmt=high&_orig=search&_sort=d&_docanchor=&view=c&_acct=C000053385&_version=1&_urlVersion=0&_userid=1510667&md5=b817a53db36dd01cf9238d7879d98e74"]

but you must know how to use Science Direct resources ("Brought to you by the Reed College Library") to gain access. Which I don't. Would love to see somebody explore this stuff, report back!